Forms the components of a diallel model for REML or regression (R.W. Payne).
No options
Parameters
MALEPARENTS = factors |
Specifies the male parents |
|---|---|
FEMALEPARENTS = factors |
Specifies the female parents |
PARENTS = matrices |
Saves design matrices for the overall parental effects |
COMPPARENTS = matrices |
Saves comparison matrices for overall parental effects |
PUREVSCROSS = factors |
Saves factors to represent the comparison between pure and crossed lines |
CROSSPAIR = factors |
Saves factors to represent the comparison between types of pairs of parent (ignoring the individual genders) |
Description
FDIALLEL forms the factors and matrices that are needed to specify and fit a diallel model using Genstat REML or regression.
The factors identifying the male and female parent of each line are specified by the MALEPARENTS and FEMALEPARENTS parameters, respectively. The PARENTS parameter saves a design matrix that can be used in REML to represent the overall effects of each parental line, and the COMPPARENTS parameter saves the transpose of the matrix. You can use COMPPARENTS as the third argument of the COMPARISON function to fit the parental effects in a Genstat regression model. The PUREVSCROSS parameter saves a factor to represent the comparison between pure and crossed lines, and the CROSSPAIR parameter saves a factor representing the comparison between types of pairs of parent (ignoring their individual genders).
The examples for FDIALLEL (which can be accessed by using the LIBEXAMPLE procedure or the Examples menu in Genstat for Windows) show how these factors and matrices can be used in Genstat REML and regression to generate the analyses of Hayman (1954) and Jones (1965), provided by the DIALLEL procedure. The terms in the DIALLEL analysis correspond to those in the FDIALLEL analysis as follows.
a: variation between mean effects of each parental line; this corresponds to PARENTS in REML, or COMP(Vdum; np; COMPPARENTS) in regression (where vdum is a dummy variate, containing any values, and np is the number of different types of parental line).
b1: assesses whether dominance is largely uni-directional; corresponds to PUREVSCROSS.
b2: estimates “asymmetry” i.e. if alleles at any one locus are not equally frequent; corresponds to PARENTS.PUREVSCROSS in REML, or COMP(Vdum; np; COMPPARENTS).PUREVSCROSS in regression.
b3: signifies that some dominance is peculiar to individual crosses; corresponds to CROSSPAIR.
c: variation between average maternal effects of each parental line; corresponds to FEMALEPARENT.
d: variation in the reciprocal differences not attributable to c; corresponds to MALEPARENT.FEMALEPARENT.
Options: none.
Parameters: MALEPARENTS, FEMALEPARENTS, PARENTS, COMPPARENTS, PUREVSCROSS, CROSSPAIR.
Action with RESTRICT
FDIALLEL ignores restrictions i.e. it forms the factors and matrices using all the units of MALEPARENTS and FEMALEPARENTS.
References
Hayman, B.I. (1954). The Analysis of Variance of Diallel Tables. Biometrics, 10, 235-244.
Jones, R.M. (1965). Analysis of Variance of the Half Diallel Table. Heredity, 20, 117-121.
See also
Procedures: DIALLEL, FCONTRASTS.
Commands for: Regression analysis, REML analysis of linear mixed models.
Example
CAPTION 'FDIALLEL examples',\
!t('Data from Hayman, B.I. (1954). Biometrics 10, 235-244.',\
'Two blocks of 8 x 8 full diallel tables.'); STYLE=meta,plain
TEXT [VALUES=one,two,three,four,five,six,seven,eight] Parents
FACTOR [NVALUES=128; LABELS=Parents] Male,Female
FACTOR [NVALUES=128; LEVELS=2] Blocks
READ Blocks,Female,Male,Y; FREPRESENTATION=levels,2(labels),*
1 one one 276 1 one two 156 1 one three 322 1 one four 250
1 one five 162 1 one six 193 1 one seven 222 1 one eight 152
1 two one 136 1 two two 166 1 two three 164 1 two four 134
1 two five 102 1 two six 150 1 two seven 96 1 two eight 90
1 three one 246 1 three two 158 1 three three 416 1 three four 213
1 three five 160 1 three six 222 1 three seven 128 1 three eight 166
1 four one 318 1 four two 132 1 four three 218 1 four four 272
1 four five 138 1 four six 195 1 four seven 108 1 four eight 124
1 five one 150 1 five two 124 1 five three 164 1 five four 164
1 five five 156 1 five six 158 1 five seven 100 1 five eight 114
1 six one 182 1 six two 136 1 six three 204 1 six four 216
1 six five 133 1 six six 174 1 six seven 112 1 six eight 120
1 seven one 174 1 seven two 86 1 seven three 194 1 seven four 142
1 seven five 86 1 seven six 92 1 seven seven 58 1 seven eight 94
1 eight one 152 1 eight two 128 1 eight three 158 1 eight four 136
1 eight five 126 1 eight six 114 1 eight seven 84 1 eight eight 142
2 one one 302 2 one two 178 2 one three 274 2 one four 246
2 one five 140 2 one six 204 2 one seven 254 2 one eight 154
2 two one 142 2 two two 175 2 two three 136 2 two four 128
2 two five 128 2 two six 174 2 two seven 116 2 two eight 114
2 three one 242 2 three two 174 2 three three 360 2 three four 178
2 three five 140 2 three six 208 2 three seven 160 2 three eight 154
2 four one 204 2 four two 138 2 four three 206 2 four four 210
2 four five 130 2 four six 192 2 four seven 138 2 four eight 176
2 five one 180 2 five two 140 2 five three 156 2 five four 146
2 five five 176 2 five six 192 2 five seven 104 2 five eight 170
2 six one 186 2 six two 146 2 six three 202 2 six four 222
2 six five 150 2 six six 166 2 six seven 136 2 six eight 176
2 seven one 162 2 seven two 100 2 seven three 162 2 seven four 100
2 seven five 98 2 seven six 84 2 seven seven 48 2 seven eight 142
2 eight one 154 2 eight two 138 2 eight three 140 2 eight four 144
2 eight five 124 2 eight six 112 2 eight seven 96 2 eight eight 166 :
CAPTION 'Hayman analysis'; STYLE=meta
" form factors and matrices for analysis "
FDIALLEL MALEPARENTS=Male; FEMALEPARENTS=Female; PARENTS=Parent;\
COMPPARENTS=Parentm; PUREVSCROSS=Pure_vs_Cross; CROSSPAIR=b3
VARIATE [VALUES=128(0)] Parentv
MODEL Y
FIT [PRINT=accumulated; NOMESSAGE=aliasing] \
Blocks + (Pure_vs_Cross * COMP(Parentv;8;Parentm)) \
+ b3 + Female + Male.Female \
+ Blocks.(Pure_vs_Cross * COMP(Parentv;8;Parentm)) \
+ Blocks.(b3 + Female)
VCOMPONENTS [FIXED=Blocks + (Pure_vs_Cross * Parent) \
+ b3 + Female + Male.Female \
+ Blocks.(Pure_vs_Cross * Parent) \
+ Blocks.(b3 + Female)]
REML Y
CAPTION 'Griffing analysis'; STYLE=meta
" form factors and matrices for analysis "
FDIALLEL MALEPARENTS=Male; FEMALEPARENTS=Female; PARENTS=GCA;\
COMPPARENTS=GCAm; CROSSPAIR=SCA
VARIATE [VALUES=128(0)] GCAv
MODEL Y
FIT [PRINT=accumulated; NOMESSAGE=aliasing] \
Blocks + COMP(GCAv;8;GCAm) + SCA + Female + Male.Female
VCOMPONENTS [FIXED=Blocks + GCA + SCA + Female + Male.Female]
REML Y
CAPTION 'Compare with DIALLEL '; STYLE=meta
" put data into two matrices (one for each block) as required by DIALLEL "
MATRIX [ROWS=8; COLUMNS=8] Blockdat[1...2]
EQUATE Y; NEWSTRUCTURE=Blockdat
DIALLEL [PRINT=aov,griffing; LABELS=Parents] Blockdat[]
CAPTION !t('Data from Jones, R.M. (1965). Heredity 20, 117-121.',\
'Single block of half diallel.')
FACTOR [NVALUES=10; LEVELS=4] male,female
READ male,female,y
1 1 33.9 1 2 42.0 1 3 35.6 1 4 38.7
2 2 31.0 2 3 36.7 2 4 39.1
3 3 30.0 3 4 34.5
4 4 32.8 :
CAPTION 'Hayman analysis'; STYLE=meta
" form factors and matrices for analysis "
FDIALLEL MALEPARENTS=male; FEMALEPARENTS=female; PARENTS=parent;\
COMPPARENTS=parentm; PUREVSCROSS=pure_vs_cross; CROSSPAIR=b3
CALCULATE parentv = y - y
MODEL y
FIT [PRINT=accumulated; NOMESSAGE=aliasing] \
(COMP(parentv;3;parentm) * pure_vs_cross) + b3
" regression analysis shows that b3 has to be used as the residual "
VCOMPONENTS [FIXED=parent * pure_vs_cross]
REML y
CAPTION 'Compare with DIALLEL '; STYLE=meta
" read data in a matrix (as required for DIALLEL) "
MATRIX [ROWS=4; COLUMNS=4] Data
READ Data
33.9 42.0 35.6 38.7
0 31.0 36.7 39.1
0 0 30.0 34.5
0 0 0 32.8 :
DIALLEL [PRINT=aov; METHOD=half] Data