Calculates Affymetrix expression values (D.B. Baird).
Options
PRINT = string token |
What to print (estimates, monitoring); default esti |
|---|---|
METHOD = string token |
Method of establishing grid background (rma, rma2, moments, maximumlikelihood); default rma |
NORMALIZED = string token |
Whether slides have been normalized (yes, no); default no |
Parameters
DATA = variates or pointers |
Perfect-match data |
|---|---|
SLIDES = factors or texts |
Defines the slides |
NEWDATA = variates or pointers |
Saves the corrected values; if this is unset, they replace the original values in DATA |
ESTIMATES = variates |
Saves the estimated parameters of the model |
Description
MARMA estimates expression values over the perfect match (PM) values for each probe on Affymetrix slides/chips. On Affymetrix chips, each probe has 8-20 pairs of DNA sequences with a central base changed between perfect match and mismatch sequences. With the robust means analysis (RMA) the value for the probe level of expression is taken as an average over the perfect-match spots, after removing any estimated noise effects, ignoring the mismatch spots. The DATA parameter supplies the PM values from the slides, in either a stacked or an unstacked representation. With stacked data, the observations from all the slides are supplied by the DATA parameter in a single variate, and the SLIDES factor indicates the slide on which each observation was made. With unstacked data, the DATA parameter supplies a pointer with a variate for each slide. The SLIDES parameter can be omitted, or can supply a text defining a label for each slide.
The default setting of the METHOD option uses the RMA probe-level model, introduced by Irizarry et al. (2003), which uses only PM information and transforms the values based on a kernel density estimate of the PM distribution. The rma2 setting uses an adaptation of the algorithm, which fits the kernel density to a truncated distribution of the perfect-match values, with the truncation point based on an initial kernel density estimate. The moments setting uses the method of moments, and the maximumlikelihood setting uses maximum likelihood to estimate the background noise in the PM distribution.
Options: PRINT, METHOD, NORMALIZED.
Parameters: DATA, SLIDES, NEWDATA, ESTIMATES.
References
Irizarry, R.A., Hobbs, B., Collin, F., Beazer-Barclay, Y.D., Antonellis, K.J., Scherf, U. & Speed, T.P. (2003). Exploration, normalization, and summaries of high density oligonucleotide array probe level data. Biostatistics, 4, Number 2, 249-264.
See also
Procedures: AFFYMETRIX, FDRBONFERRONI, FDRMIXTURE, MAANOVA, MABGCORRECT, MAEBAYES, MAREGRESSION, MAROBUSTMEANS, MAVDIFFERENCE, MAVOLCANO, QNORMALIZE.
Commands for: Microarray data.
Example
CAPTION 'MARMA example'; STYLE=meta
ENQUIRE CHANNEL=-1; EXIST=check; NAME=\
'%GENDIR%/Data/Microarrays/HybStds.gwb'
IF check
SPLOAD '%GENDIR%/Data/Microarrays/HybStds.gwb'
" Convert Data into PM/MM columns."
SORT [INDEX=Slide,Probe,Atom] Slide,Probe,Atom,PM_MM,Intensity
SUBSET [PM_MM .in. 'MM'] Intensity; MM
SUBSET [PM_MM .in. 'PM'] Slide,Probe,Atom,Intensity
CALC LogPM = LOG(Intensity)
CALC LogMM = LOG(MM)
DELETE [REDEFINE=yes] Intensity,ROW,COL,PM_MM,MM
TRELLIS [GROUPS=Slide; NGROUPS=100; TITLE='Log(PM) by Slide']\
LogPM; METHOD=Histogram
" Standard RMA method."
MARMA [METHOD=rma; NORMALIZED=no] LogPM; SLIDES=Slide; NEWDATA=ALogPM
TRELLIS [GROUPS=Slide; NGROUPS=100; TITLE='RMA Adjusted Log(PM) by Slide']\
ALogPM; METHOD=Histogram
" Using method of moment estimator for parameters (much faster)."
MARMA [METHOD=moments; NORMALIZED=no] LogPM; SLIDES=Slide; NEWDATA=ALogPM
TRELLIS [GROUPS=Slide; NGROUPS=100;\
TITLE='Moments Adjusted Log(PM) by Slide'] ALogPM; METHOD=Histogram
" Using maximum likelihood estimation for parameters (more accurate)."
MARMA [METHOD=maximumlikelihood; NORMALIZED=no] LogPM; SLIDES=Slide;\
NEWDATA=ALogPM
TRELLIS [GROUPS=Slide; NGROUPS=100;\
TITLE='Maximum Likelihood adjusted Log(PM) by Slide']\
ALogPM; METHOD=Histogram
ELSE
CAPTION 'Microarray example datasets have not been installed.'
ENDIF