Displays results of t-tests for pairwise differences in compact diagrams (P.W. Goedhart, H. van der Voet & D.C. van der Werf).
Options
PRINT = string token |
What to print (items, groups); default grou |
|---|---|
PROBABILITY = scalar or symmetric matrix |
Level of significance of pairwise comparison tests; default 0.05 |
Parameters
TPROBABILITIES = symmetric matrices |
Probabilities of tests of pairwise comparisons |
|---|---|
DIFFERENCES = symmetric matrices, variates or tables |
What to print alongside the labels of TPROBABILITIES; default * |
LABELS = texts |
Text vector labelling the output; if unset the row labels of TPROBABILITIES and the diagonal of DIFFERENCES (if set) are used |
ITEMLETTERS = texts |
Saves the letters showing the items not significantly different from each item |
GROUPLETTERS = texts |
Saves the letters showing groups of items not significantly different from each other |
Description
Procedures RPAIR and PAIRTEST produce a symmetric matrix of two-sided t-probabilities for tests of all pairwise differences of estimates. PPAIR displays this matrix at a specified level of significance in two compact schematic diagrams. This is especially useful when the number of estimates is large.
Input to PPAIR is a symmetric matrix TPROBABILITIES containing probabilities of the set of pairwise comparisons. The level of significance can be set by the PROBABILITY option. A common level is specified by a scalar, while a symmetric matrix specifies a level for each comparison separately (which may be useful for some multiple comparison methods). Output is labelled by the row labels of TPROBABILITIES. If parameter DIFFERENCES is set to a symmetric matrix the diagonal of this matrix is printed alongside these labels (with number of decimals as defined at declaration of DIFFERENCES). This is especially useful if DIFFERENCES is saved by RPAIR or PAIRTEST because it then contains the estimates on the diagonal. DIFFERENCES can also be set to a variate or table. Alternatively the output can be labelled by specifying parameter LABELS.
PRINT controls which diagram is printed. PRINT=items produces a diagram which should be read line by line. Each item (represented by a letter) is followed by those items (again represented by letters) not significantly different from that item. When there are more than 52 items, letters are repeated. PRINT=groups is only useful when the TPROBABILITIES are sorted in a sensible order, for example by specifying SORT=yes in RPAIR or PAIRTEST. This produces a diagram in which items followed by a common letter are not significantly different. Such items are said to form a homogeneous group. This is similar to common underlining of items with non-significantly different estimates. In constructing this diagram the philosophy of multistage testing is followed, see the Method section. The letters can be saved, in texts, by the ITEMLETTERS and GROUPLETTERS parameters.
Options: PRINT, PROBABILITY.
Parameters: TPROBABILITIES, DIFFERENCES, LABELS, ITEMLETTERS, GROUPLETTERS.
Method
The construction of the diagram for PRINT=groups is as follows. First the difference between the first and last item of the complete set of n items is checked for significance. Then the first and last item of all subsets of n-1 consecutive items are checked, followed by all subsets of n-2 items, and so on. If non-significance is found between the first and last item of a subset, all items of the subset are said to form a homogeneous group and they receive the same letter. This is only sensible when the TPROBABILITIES are sorted according to the estimates. The diagram only consists of homogeneous groups which are not a part of a larger group.
It is obvious that items in a homogeneous group can be significantly different. This is not displayed in the diagram, although a message is printed if this occurs. If there are no significant differences within homogenous groups, both diagrams essentially contain the same information; PRINT=groups then gives a more concise representation.
Action with RESTRICT
Restrictions on DIFFERENCES and LABELS are ignored.
See also
Procedures: ALLDIFFERENCES, AMCOMPARISON, AUMCOMPARISON, PAIRTEST, RPAIR.
Commands for: Regression analysis.
Example
CAPTION 'PPAIR example',\
!t('1. Comparison of variety means in a 5x5 lattice experiment.',\
'Data from Cochran, W.G. & Cox, G.M. (1957), Experimental',\
'Designs, 2nd Ed. Wiley, New York, page 406. There are no',\
'significant differences within homogenous groups.',\
'PRINT=groups only would then be sufficient.');\
STYLE=meta,plain
FACTOR [LEVELS=2; VALUES=25(1,2)] Rep
FACTOR [LEVELS=5; VALUES=5(1...5)2] Block
FACTOR [LEVELS=25; VALUES=(1...25), (1,6...21), (2,7...22), (3,8...23),\
(4,9...24), (5,10...25)] Variety
VARIATE [VALUES= 6,7,5,8,6, 16,12,12,13,8, 17,7,7,9,14, 18,16,13,13,14,\
14,15,11,14,14, 24,13,24,11,8, 21,11,14,11,23, 16,4,12,12,12,\
17,10,30,9,23, 15,15,22,16,19] Yield
MODEL Yield
FIT [PRINT=accumulated] Rep/Block + Variety
RPAIR [SORT=yes; PRINT=*] !P(Variety); TPROBABILITIES=YieldPr;\
DIFFERENCES=YieldDif
PRINT YieldPr; FIELDWIDTH=7; DECIMALS=3
PPAIR [PRINT=items,groups] YieldPr; DIFFERENCES=YieldDif
CAPTION !t('2. Comparison of unequally replicated treatments with',\
'significant differences within homogenous groups.')
FACTOR [LABELS=!t(Aap, Noot, Mies, Wim, Zus, Jet, Vuur, Gijs);\
VALUES=7(1), 8(2), 4(3), 9(4), 1(5), 8(6), 9(7), 2(8)] Label
VARIATE [VALUES=4.58, 3.66, 4.05, 6.24, 5.70, 5.13, 5.65, 6.56, 5.24,\
6.09, 3.53, 5.77, 4.04, 4.18, 5.40, 5.93, 6.00, 6.78, 4.89,\
7.17, 5.91, 5.22, 5.34, 6.87, 7.25, 6.91, 5.26, 5.86, 6.30,\
6.89, 7.79, 7.41, 5.58, 7.17, 7.90, 6.14, 5.50, 6.58, 8.17,\
8.19, 7.55, 9.58, 7.38, 7.72, 8.00, 7.92, 7.59, 8.41] Response
MODEL Response
FIT Label
RPAIR [SORT=yes; PRINT=*] !P(Label); TPROBABILITIES=LabelPr;\
DIFFERENCES=LabelDif
PRINT LabelPr; FIELDWIDTH=7; DECIMALS=3
PPAIR [PRINT=items,groups] LabelPr; DIFFERENCES=LabelDif